Excelでフォルダ内のファイル一覧を取得するVBAサンプルコード【リンク付き】

Option Explicit
' グローバル変数
Dim RowNo As Long ' 出力行番号
Dim No As Long    ' 連番

' 一覧表示ボタン押下時
Sub ボタン1_Click()

    Application.ScreenUpdating = False   ' 画面更新停止（高速化）
    
    RowNo = 5  ' 出力開始行
    No = 1     ' 連番初期化
    
    Call ClearList
    Call FileSearch(Sheets(1).Cells(2, 2))
    
    Application.ScreenUpdating = True ' 画面更新再開
    
End Sub
' 一覧の初期化（既存行削除）
Sub ClearList()
    
    Dim lastRow As Long
    lastRow = Cells(Rows.Count, 1).End(xlUp).Row
    
    Sheets(1).Rows("5:" & Cells.Rows.Count).Delete
    
End Sub
' ファイル検索（再帰処理）
Sub FileSearch(Path As String)

    Dim FSO As Object
    Dim Folder As Variant
    Dim File As Variant
    Set FSO = CreateObject("Scripting.FileSystemObject")
    
    '--- サブフォルダを再帰検索 ---
    For Each Folder In FSO.GetFolder(Path).SubFolders
        Call FileSearch(Folder.Path)
    Next Folder
    
    '--- ファイル一覧出力 ---
    For Each File In FSO.GetFolder(Path).Files
        
        ' No
        Sheets(1).Cells(RowNo, 1).Value = No
        No = No + 1
        ' ファイル名
        Sheets(1).Cells(RowNo, 2).Value = File.Name
        ' フルパス
        Sheets(1).Cells(RowNo, 3).Value = File.Path
        ' ハイパーリンク
        Sheets(1).Hyperlinks.Add Anchor:=Cells(RowNo, 4), Address:=File.Path, TextToDisplay:="リンク"
        
        RowNo = RowNo + 1
        
    Next File
    
End Sub