文字列を分割して1文字ずつセル入力するVBAのサンプルコード

Sub splitText1record()
    
    '入力テキスト
    Dim intext As String
    intext = ActiveSheet.Cells(1, 1).Value
    
    '出力テキストのスタート位置
    Dim targetRange As Range
    Set targetRange = Range(Cells(1, 2).Address)
    
    Dim i As Long
    For i = 1 To Len(intext)
    
        'オフセットで1セルずつ右移動しながら、1文字ずつ格納
        targetRange.Offset(0, i - 1).Value = Mid(intext, i, 1)
    
    Next

End Sub

Sub splitTextFullRecord()

    '開始時間取得
    startTime = Timer

    Dim i As Long
    For i = 1 To Cells(1, 1).End(xlDown).Row
        
        '入力テキスト
        Dim intext As String
        intext = ActiveSheet.Cells(i, 1).Value
        
        '出力テキストのスタート位置
        Dim targetRange As Range
        Set targetRange = Range(Cells(i, 2).Address)
        
        Dim j As Long
        For j = 1 To Len(intext)
        
            'オフセットで1セルずつ右移動しながら、1文字ずつ格納
            targetRange.Offset(0, j - 1).Value = Mid(intext, j, 1)
        
        Next
        
    Next
    
    '終了時間取得
    endTime = Timer
    
    '処理時間計算
    processTime = endTime - startTime
    MsgBox "処理時間：" & processTime
    
End Sub

Sub splitTextFullRecord2()
    
    '開始時間取得
    startTime = Timer
    
    '入力テキスト(A1～A1000) セル -> 配列格納
    ReDim intext(1, Cells(1, 1).End(xlDown).Row) As Variant
    intext = Range(Cells(1, 1), Cells(Cells(1, 1).End(xlDown).Row, 1)).Value
    
    '出力テキスト(2次元配列) ※100は決め打ち。
    Dim fieldNum As Integer
    fieldNum = 100
    ReDim outText(1 To Cells(1, 1).End(xlDown).Row, 1 To fieldNum) As String
    
    Dim i As Long
    For i = 1 To UBound(intext)
    
       'A列から値取得
        Dim record As String
        record = intext(i, 1)
        
        Dim j As Long
        For j = 1 To Len(record)
        
            '1文字ずつ格納
            outText(i, j) = Mid(record, j, 1)
        
        Next
        
    Next
    
    '配列 -> セル格納
    Range(Cells(1, 2), Cells(Cells(1, 1).End(xlDown).Row, fieldNum + 1)).Value = outText
    
    '終了時間取得
    endTime = Timer
    
    '処理時間計算
    processTime = endTime - startTime
    MsgBox "処理時間：" & processTime
    
End Sub